- schneider-lastin

Sollen benutzereigene Einstellungen zu Zeichengruppen, Farben, Editormakros etc. permanent in einer TUSTEP-Sitzung zur Verfügung stehen, empfiehlt es sich, diese Definitionen mit dem Kommando #EDIERE in die INI-Datei ('tustep.ini') zu schreiben, damit sie jeweils beim Start von TUSTEP = beim Beginn einer TUSTEP-Sitzung ausgeführt werden. Das Kommando und die einschlägige Spezifikation lauten:
#EDIERE,,,DEFINITIONEN

Beispiel für die Definition einer Zeichengruppe von Vokalen sowie der Colorierung aller Tags und der mit <h1> getaggten Überschriften ersten Grades:

#E,,,*
Z:vo=aeiouäöüy
C1,1=FC:-<*>--#.<-#.>-%<-%>-
C1,2=1F:-<h1>*</h1>-
*eof

- ms.tru

Das Editorfenster kann mit den Kommandos

#E,ZEILEN=zahl
#E,SPALTEN=zahl

bzw.

#E,SPALTEN=zahl, ZEILEN=zahl

eingestellt werden. Für die Spezifikation SPALTEN ist der Mindestwert 80 und der Maximalwert 240 vorgesehen, für ZEILEN ein Wert zwischen 10 und 120. Unter Windows und Mac OS kann für SPALTEN und ZEILEN zudem der Wert „++“ eingestellt werden, wodurch das Fenster an die Bildschirmgröße angepasst (= maximiert) wird:

#E,ZEILEN=++
#E,SPALTEN=++
#E,SPALTEN=++, ZEILEN=++

In einer erweiterten Form der Spezifikationsangabe können per Kommando auch gleich die Höhen bzw. Breiten für das gesamte Editorfenster sowie die (bei Teilung des Fensters) oberen und unteren bzw. linken und rechten Fensterhälften eingestellt werden:

#E,ZEILEN=n;no;nu
#E,SPALTEN=n;nl;nr
#E,ZEILEN=n;no;nu, SPALTEN=n;nl;nr

Dabei gilt gemäß Beschreibung:
„Höhe des Editor-Fensters auf n (n = 10 bis 120 oder ++ oder +) Zeilen einstellen. Falls das Textfeld horizontal unterteilt wird, oberes Textfeld auf no (no = 3 bis 110) und unteres auf nu (nu = 3 bis 110) Zeilen einstellen.“ bzw. „Breite des Editor-Fensters auf n (n = 80 bis 240 oder ++ oder +) Spalten einstellen. Falls das Textfeld vertikal unterteilt wird, linkes Textfeld auf nl (nl = 40 bis 200) und rechtes auf nr (nr = 40 bis 200) Spalten einstellen.“

Alternativ kann innerhalb des Editors nach Aufruf der Tastenkombination STRG+L die Größe für das Editorfenster bzw. für die Teilfenster (im geteilten Bildschirmmodus) eingestellt werden.

- ms.tru

Die hier gegebenen Editordefinitionen sind exemplarisch und können benutzt werden, um diverse Einstellungen für den Editor dauerhaft abzulegen.
Beispielhaft sind hier zu nennen: Größe des Editorfensters, Einstellung der Farben, Tastenkombinationen (Tastaturmakros), Mausleisten und ähnliches mehr.
Das Script ist als MAKRO konzipiert, die Datei 'editor.tf' kann daher von der Kommandoebene mit #t,editor.tf ausgeführt werden.
In einer getrennten Einführung soll gezeigt werden, wie die einzelnen Bestandteile der Editordefinitionsdatei erstellt werden können (siehe z.B. unter Colorierung). Die hier vorliegende Datei soll lediglich als Beispiel und Anschauungsmaterial dienen.

editor.tf [8 KB]

#- Diese Datei dient der Einstellung von verschiedenen benutzerspezifischen
#- Präferenzen für den Editor.

#makro
#= ================================
#- Definition der Größe des TUSTEP-Fensters:
#= ================================
#= Einschalten des TUSCRIPT-Modus:
$$ MODE TUSCRIPT
#= Definition von paar Variablen, die im Folgenden
#= benutzt werden sollen:

SET tstpver = VERSION (NAME)
SET compile = VERSION (COMPILED)
SET username = USER ()
SET system = SYSTEM()

-   Anpassung der Fenstergröße an den Bildschirm unter Windows:
IF (system .EQ. "WIN") THEN
    - Einstellung des Tustep-Fensters auf die Desktop-Größe:
    -  maximale Fenstergröße -10 bzw. 50:
    SET hoehe  = ROWS (LIMIT), hoehe = hoehe - 10
    SET breite = COLS (LIMIT), breite = breite - 50
    DATA #de,zei={hoehe};800,spa={breite}

-  Ausgabe von zusätzlichen Informationen:
+  Sie, {username},  nutzen {system}. Das TUSTEP-Fenster wird
+  in Abhängigkeit von der Bildschirmgröße eingestellt.
+  Genutzte TUSTEP-Version: {tstpver}. {compile}.

   -Einstellung des TUSTEP-Fensters unter Linux:
     -hier ggf. von Hand die Angaben ändern, da bisher keine
     - automatische Anpassung an die Fenstergröße möglich
ELSE IF (system .EQ. "LINUX") THEN
    DATA #de,zei=33;800,spa=90
+  Sie, {username}, nutzen {system}. Das TUSTEP-Fenster wird gemäß
+  Voreinstellung definiert.
+  Genutzte TUSTEP-Version: {tstpver}. {compile}.
ENDIF

*eof
#- Signalton (akustische Fehlermeldung) deaktivieren:
#de,sign=-

#- ================================
#- Hier Beginn der eigentlichen Editordefinitionen
#- ================================
#ed,,,*

=  * Editor-Definitionen (Farben, Cursor etc.):
O=00000033 805B8B4E0C-715EF14E0A-1A4EF4-715BF2F90A-1A4EF4-711BF4 010102050000F1FF 010001 5050283C5001FF 2A
tab,, 7 11 21 31
= ================================
=   Zeichen- und Stringgruppendefinitionen
= ================================
=  * Vokale:
c:vo=aeiouäöüy
c:v0=aeiou

=  * Präfixe im Deutschen:
s:pf=|an|auf|aus|ent|gegen|her|hin|nach|über|un|unter|ver|vor|zu|

=  * Suffixe im Deutschen:
s:sf=|heit|heiten|keit|nis|nisse|nissen|ung|ungen|

=  * Nichtblanks:
c:nb=?{-} {+}

=  * Konsonanten (alle Buchstaben außer die Vokale):
c:ks={&a}{-}aeiouäöüy

=  * Wortseparatoren / Satzzeichen:
c:sz=.,: ;-!"?()[] +/&$%=#
s:sz=|{c:sz}|»|«|„|“|”|§|

=  * Zeichen, die in HTML/XML-Tags vorkommen können
c:tz=?{-}<>

= ================================
= Funktionstastenbelegungen:
= ================================
= Deaktivieren der "beende"-Funktion auf F3
= zur Vermeidung von irrtümlichen Befehlen:
f3=

= Ausführen der aktuellen (Programm-)Editordatei als normales TUSTEP-Programm:
f16=x #t,<editor>
=  ... oder als Makro:
f17=x #ma,<editor>

= Anzeigen von TUSTEP-Beschreibungen mittels der hierfür vorgesehenen
=  Standardmakros:
f50=x #*zebe
f51=x #*zebe,import
f52=x #*zebe,satzmakro

= ================================
=   Tastaturmakrodefinitionen:
= ================================
=   Einfügen bzw. Entfernen von drei BLANKS am linken Rand des aktuellen
=    Datensatzes (=Kommentarfunktion in einem Programmskript):
=     CA = STRG + ALT + folgender Buchstabe, z.B.
=     1. "STRG + ALT + I"  zum Einfügen der Blanks:
Y,CA_I=BEG REC,INS:|   |,NEXT REC
Y,CA_D=BEG REC,3*DEL BLANK,NEXT REC

=   Rahmen für Zeigeanweisungen vorgeben, Cursor springt in die Suchzeichen:
Y,CA_N=CMD LINE,CLR LINE,"zn,,,||",CUR LE
Y,CA_U=CMD LINE,CLR LINE,"zu,,,||",CUR LE
=   Anfangstag für Kursivierung einsetzen.
=   Sämtliche Tags können automatisch mit "ALT + E" geschlossen werden.
Y,CA_K=INS:"<i>"
=   Einfügen eines häufig benutzen Zeichens:
Y,CA_L=INS:"→"

=   Rahmen für einen bibliographischen Eintrag:
=   hier Monographie:
Y,CA_M=CONFIRM,"ze",ENTER,CUR UP,SPLIT,
   "<author></author>",split,
   "<title></title>",split,
   "<subtitle></subtitle>",split,
   "<series></series>",split,
   "<place></place>",split,
   "<date></date>",split,
   "<url></url>",split,
   "<keywords></keywords>",split,7*CUR UP,9*CUR_RI
= ================================
= Colorierungs-Definitionen:
= ================================
=     Belegung der Colorierungsgruppe 8,1 und 8,2 mit den
=     Farben 1B und 74 (s. STRG + F) für die dahinter stehenden
=     Zeichenfolgen
=     1. beliebiges öffnendes oder schließendes Tag
C8,1=1B:|<{0}/{00}{c:tz}>|

=     2. Milestones
C8,2=74:|<{00}{c:tz}/>|
*eof

- schneider-lastin

Folgendes Kommando löscht alle (benutzereigenen) Definitionen und übernimmt die voreingestellten Definitionen:

#E,,,-STD-

Zurück zur Übersichtsseite - Editor