Benutzer-Werkzeuge

Webseiten-Werkzeuge


Seitenleiste

tuscript:tutorial:lektion_4

Zurück zum Inhaltsverzeichnis - Erste Schritte



Lektion 4: Variablen im Script

- [ HaReTri | HaReTri ]

Lernziele
Anwendung von Variablen in einem Script



Um mit einer Variable zu arbeiten, gibt man entweder nur den Variablennamen oder den Variablennamen in geschweiften Klammern an - dies hängt von der Anweisung ab, mit der die Variable verarbeitet wird.

Zunächst definieren wir eine Variable:

$$- Variablen im Script
$$ MODE TUSCRIPT,{}
SET person = "Pippi Langstrumpf"

Die Anweisung PRINT kann den Inhalt einer Variablen einfach ausgeben:

$$- Variablen im Script
$$ MODE TUSCRIPT,{}
SET person = "Pippi Langstrumpf"
PRINT person

Soll die Anweisung PRINT aber einen Text ausgeben, der eine Variable enthält, müssen wir diese Variable mit den geschweiften Klammern kennzeichnen, damit sie nicht für einen Teil des Textes gehalten wird:

$$- Variablen im Script
$$ MODE TUSCRIPT,{}
SET person = "Pippi Langstrumpf"
PRINT "Wer wohnt in der Villa Kunterbunt? {person}."

Bevor die Zeile mit der Anweisung PRINT ausgeführt wird, wird statt {person} der Inhalt der Variablen person eingesetzt - in diesem Fall, als ob die Zeile PRINT „Wer wohnt in der Villa Kunterbunt? Pippi Langstrumpf.“ lauten würde.

Die geschweiften Klammern als Kennzeichen einer Variablen sind durch MODE TUSCRIPT voreingestellt. Sollte man sie zu einem anderen Zweck benötigen, kann man mit = eine der anderen Klammern - < ( [ - als Kennzeichen festlegen, in unserem Beispiel statt { } die [ ]:

$$- Variablen im Script
$$ MODE TUSCRIPT,{}
SET person = "Pippi Langstrumpf"
PRINT "Wer wohnt in der Villa Kunterbunt? {person}."
= [ ]
PRINT "Wer wohnt in der Villa Kunterbunt? [person]."


Sternvariablen
kann man nicht auf diese Weise von PRINT verarbeiten lassen, das folgende Script würde bei der Ausführung die Fehlermeldung „Variable BEWOHNER ist eine Sternvariable“ erhalten:

$$- Variablen im Script
$$ MODE TUSCRIPT,{}
SET bewohner = *
DATA Pippi Langstrumpf
DATA Herr Nilsson (Affe)
DATA Kleiner Onkel (Pferd)
PRINT "Wer wohnt in der Villa Kunterbunt? {bewohner}."

Alternative 1 für die letzte Zeile:

PRINT "Wer wohnt in der Villa Kunterbunt?"
* {bewohner}

Dabei steht „*“ für die Makroanweisung „$$*“ = Meldung.
Wenn diese Anweisung eine Sternvariable enthält, so wird die Meldung so oft ausgegeben, wie die Sternvariable Zeilen enthält. Die Meldung darf nur eine einzige Sternvariable enthalten.

Alternative 2:

PRINT "Wer wohnt in der Villa Kunterbunt?"
LOOP namen = bewohner
PRINT namen
ENDLOOP


Was haben wir gelernt?

  • Bei der Verarbeitung von Variablen wird entweder nur der Variablenname oder der Variablenname in geschweiften Klammern angegeben.
  • Bei der Angabe in geschweiften Klammern werden vor der Verarbeitung der Zeile die Klammern und der Variablenname durch den Inhalt der Variablen ersetzt.
  • Welche Klammern zur Kennzeichnung einer Variablen dienen sollen, kann man selbst einstellen.
  • Sternvariablen können nicht mit PRINT ausgegeben werden.

Zurück zum Inhaltsverzeichnis - Erste Schritte

tuscript/tutorial/lektion_4.txt · Zuletzt geändert: 2021/03/16 05:34 (Externe Bearbeitung)